cjs_draw_xy.ncl

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; sub.cjs_draw_xy.ncl
; Carl Schreck (cjschrec@ncsu.edu)
; April 2014
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Copyright (c) 2010, North Carolina State University
; All rights reserved.
; This work licensed under BSD 3-Clause License. Full terms in LICENSE.txt
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


undef ( "cjs_draw_xy" )
function cjs_draw_xy( \
  io_wks         [1] : graphic, \
  i_xData            : numeric, \
  i_yData            : numeric, \
  i_res          [1] : logical \
)
begin ; cjs_draw_xy
  ; These are some parameters that could be useful to have up top

  yDims = dimsizes(i_yData)
  xDims = dimsizes(i_xData)
  if( dimsizes(xDims).gt.1 )
    nCurves = xDims(0)
  else if( dimsizes(yDims).gt.1 ) then
    nCurves = yDims(0)
  else
    nCurves = 1
  end if
  end if

  ; Customize base plot
  res = cjs_fontHeightF( i_res )
  res@gsnDraw  := False
  res@gsnFrame := False
  if( isatt( i_yData, "long_name" ) ) then
    res@gsnLeftString  := i_yData@long_name
  end if
  res@gsnRightString := ""

  if( isatt( i_xData, "units" ) ) then
    res@tiXAxisString := i_xData@units
  end if
  if( isatt( i_yData, "units" ) ) then
    res@tiYAxisString := i_yData@units
  end if
  if( ( isatt( i_res, "tmYLLabelsOn" ) ).and.( .not.i_res@tmYLLabelsOn ) ) then
    res@tiYAxisString := ""
  end if
  if( ( isatt( i_res, "tmXBLabelsOn" ) ).and.( .not.i_res@tmXBLabelsOn ) ) then
    res@tiXAxisString := ""
  end if

  ; ...make gridlines look nice
  res@tmXMajorGridLineDashPattern := 2.
  res@tmYMajorGridLineDashPattern := 2.
  res@tmXMajorGridThicknessF      := 1.
  res@tmYMajorGridThicknessF      := 1.

  res@xyCurveDrawOrder := "PostDraw"

  ; ...set up an x-y line graph
  res@gsnYRefLine := 0
  res@gsnYRefLineColor := "black"
  res@gsnYRefLineThicknessF := 2
  res@gsnXRefLine := 0
  res@gsnXRefLineColor := "black"
  res@gsnXRefLineThicknessF := 2
  res@xyMarkLineMode      := "Lines"
  if( ( nCurves.eq.1 ).and.isatt( i_res, "gsnYRefLine" ) ) then
;   res@gsnBelowYRefLineColor := (/ "blue", "transparent" /)
;   res@gsnAboveYRefLineColor := (/ "transparent", "red" /)
;   res@gsnYRefLine := (/ -1, 1 /)
    res@gsnBelowYRefLineColor := "blue"
    res@gsnAboveYRefLineColor := "red"
  else
    res@xyMonoDashPattern   := .not.isatt( i_res, "xyDashPatterns" )
    res@xyLineColors        := (/ "indianred1", "skyblue3", "orchid4", "tan1", \
        "pink1", "darkslategray3", "thistle3", "khaki3" /)
    if( isatt( i_res, "xyColorMap" ) \
        .and.( str_lower(i_res@xyColorMap).eq."bold" ) ) then
      res@xyLineColors     := (/ "red", "blue", "purple", "orange",  \
          "magenta", "cyan", "seagreen", "brown" /)
    end if
    if( isatt( i_res, "xyColorMap" ) \
        .and.( str_lower(i_res@xyColorMap).eq."nca" ) ) then
      res@xyLineColors     := (/ "steelblue", "chocolate2", "chartreuse4", \
          "lightgoldenrod1", "purple4", "firebrick" /)
    end if
    if( isatt( i_res, "xyLineColors" ) ) then
      res@xyMarkerColors      := i_res@xyLineColors
    else
      res@xyMarkerColors      := res@xyLineColors
    end if
    res@xyMarkers           := (/  16,   6,  2,  5,  7,  8,  9, 12 /)
    res@xyMarkerThicknessF := 2
    res@xyLineThicknessF   := 2
;   res@xyMarkerThicknesses := (/   1,   1,  1,  1,  1,  1,  1,  1 /) * 2
;   res@xyLineThicknesses   := (/   1,   1,  1,  1,  1,  1,  1,  1 /) * 2
    res@xyMarkerSizes       := (/   1, 1,  1,  1,  1,  1,  1,  1 /) * 0.007
   
  end if

  if( i_res ) then
    copy_VarAtts( i_res, res )
  end if
  delete(res@fontHeightF)
  if( isatt( res, "xyColorMap" ) ) then
    delete(res@xyColorMap)
  end if
  if( isatt( i_res, "xyExplicitLabels" ) ) then
;   res@xyExplicitLabels       := " " + i_res@xyExplicitLabels
  end if

  print_clock( "Drawing the plot" )

  retVal = gsn_csm_xy( io_wks, i_xData, i_yData, res )

  if( isatt( i_res, "xyExplicitLabels" ) \
      .or.( ( isatt(i_res, "pmLegendDisplayMode") ) \
      .and.( i_res@pmLegendDisplayMode.eq."Always" ) ) ) then

    ; ...set up the legend
    genRes = True
    genRes@simple = True
    genRes = pick_legend_corner( i_xData, i_yData, genRes )


    lineRes = True
    lineRes@lgLineColors = res@xyLineColors(:nCurves-1)
    lineRes@lgLineThicknesses = res@xyLineThicknessF
    if( .not.res@xyMonoDashPattern ) then
      lineRes@lgMonoDashIndex = True
      lineRes@lgDashIndexes = res@xyDashPatterns
    end if

    textRes = True
    textRes@lgLabels = res@xyExplicitLabels
    textRes@lgLabelFontHeights     := res@gsnLeftStringFontHeightF * 0.75

    retVal = simple_legend( io_wks, retVal, genRes, lineRes, textRes )
  end if


  return(retVal)
end; cjs_draw_xy