cjs_shade_defaults.ncl

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; cjs_shade_defaults.ncl
; Carl Schreck (cjschrec@ncsu.edu)
; April 2014
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Copyright (c) 2010, North Carolina State University
; All rights reserved.
; This work licensed under BSD 3-Clause License. Full terms in LICENSE.txt
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


undef ( "cjs_shade_defaults" )
function cjs_shade_defaults( \
  i_data            : numeric , \ 
  i_res         [1] : logical \
)
begin ; cjs_shade_defaults
  ; These are some parameters that could be useful to have up top

  ; Customize base plot
  res = cjs_fontHeightF( i_res )
  res@gsnDraw  := False
  res@gsnFrame := False
; res@gsnLeftString  := ""
  res@gsnRightString := ""
  res@gsnCenterString := ""

  ; ...standardize the font sizes
  res@lbTitleFontHeightF        := res@fontHeightF
  res@lbLabelFontHeightF        := res@fontHeightF

  ; ...shading resources
  res@cnFillOn        := True
  res@cnFillMode      := "AreaFill"
  res@cnFillPalette   := "colorbrewer_coldhot"
; res@cnFillPalette   := reverse_colormap("MPL_RdBu")
  res@cnRasterSmoothingOn := False
  res@cnMonoFillColor := False
  res@cnInfoLabelOn   := False
  res@cnLineLabelsOn  := False
  res@cnLinesOn       := False
  res@cnLineColor     := "gray"
  res@cnMissingValFillPattern := "SolidFill"
  res@cnMissingValFillColor   := "gray"
  res@cnFillDrawOrder := "PreDraw"

  ; ...set the contour levels
  if( isatt( i_res, "cnLevels" ) ) then
    res@cnLevelSelectionMode := "ExplicitLevels"
  else
    res@cnMaxLevelCount := 10
  end if

  ; ...labelbar resources
  res@lbLabelBarOn      := True
  if( isatt( i_res, "lbOrientation" ) \
      .and.( i_res@lbOrientation.eq."Vertical" ) ) then
    res@lbOrientation     := "Vertical"
    res@lbTitlePosition   := "Top"
    res@lbTitleDirection  := "Across"
  else
    res@lbOrientation     := "Horizontal"
;   res@lbLabelAngleF     := 90
    res@lbTitlePosition   := "Bottom"
    res@lbTitleDirection  := "Across"
;   res@pmLabelBarOrthogonalPosF := 0.60
    res@pmLabelBarHeightF        := 0.04
  end if
  if( isatt( i_data, "units" ) ) then
    res@lbTitleString     := i_data@units
  end if

  res@vpWidthF := 0.5

  ; ...make gridlines look nice
  res@tmXMajorGridLineDashPattern := 2.
  res@tmYMajorGridLineDashPattern := 2.
  res@tmXMajorGridThicknessF      := 1.
  res@tmYMajorGridThicknessF      := 1.

  if( i_res ) then
    copy_VarAtts( i_res, res )
  end if

  return(res)
end; cjs_shade_defaults